DOS编程6-IF命令

本章介绍IF命令的用法。

基本语法

在CMD使用IF /?打开IF的系统帮助，会发现IF有3种基本的用法，来执行批处理程序中的条件处理。

IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command

用法详解

NOT：指定只有条件为 false 的情况下， Windows才应该执行该命令。
ERRORLEVEL number：如果最后运行的程序返回一个等于或大于指定数字的退出编码，指定条件为 true。
string1==string2：如果指定的文字字符串匹配，指定条件为 true。
EXIST filename： 如果指定的文件名存在，指定条件为 true。
command：如果前面的条件为True时，指定要执行的命令。如果指定的条件为 FALSE，命令后可跟一个执行 ELSE 关键字后的命令的 ELSE 命令。

ELSE 子句必须在 IF 之后出现在同一行上。例如:

IF EXIST filename (
del filename
) ELSE (
echo filename missing
)

¶用法1：IF [NOT] ERRORLEVEL number command

这个用法的基本做用是判断上一条命令执行结果，以决定下一个步骤。一般上一条命令的执行结果只有两个，"成功"用0表示 "失败"用1表示。
举个例子:

@echo off
net user
IF %ERRORLEVEL% == 0 echo net user 执行成功了!
pause

这是个简单判断上条命令是否执行成功。细心的朋友可能会发现，这个用法和帮助里的用法不太一样，按照帮助里的写法IF %ERRORLEVEL% == 0 echo net user 执行成功了!这一句代码应该写成:IF ERRORLEVEL 0 echo net user 执行成功了!，那为什么我要写成这样呢？各位自己把代码改掉执行后，就会发现错误了！用这种语法，不管你的上面的命令是否执行成功，他都会认为命令成功了，不知道是BUG还是本人理解错误…

补充：
  这不是bug，而是 if errorlevel 语句的特点：当使用 if errorlevel 0 …… 的句式时，它的含义是：如果错误码的值大于或等于0的时候，将执行某个操作；当使用 if %errorlevel%==0 …… 的句式时，它的含义是：如果错误码的值等于0的时候，将执行某操作。因为这两种句式含义的差别，如果使用前一种句式的时候，错误码语句的排列顺序是从大到小排列。

  一般上一条命令的执行结果代码只有两结果，"成功"用0表示 "失败"用1表 示。这只是一般的情况，实际上，errorlevel返回值可以在0~255之间，比如，xcopy 默认的errorlevel值就有5个，分别表示5种执行状态：

退出码说明：

0. 文件复制没有错误。
1. if errorlevel 2 echo。
2. 用户按 CTRL+C 终止了 xcopy。
3. 出现了初始化错误。没有足够的内存或磁盘空间，或命令行上输入了无效的驱动器名称或语 法。
4. 出现了磁盘写入错误。

要判断上面xcopy命令的5种退出情况，应写成：

>if errorlevel 5 echo出现了磁盘写入错误
>if errorlevel 4 echo出现了初始化错误
>if errorlevel 2 echo用户按 CTRL+C 终止了 xcopy
>if errorlevel 1 echo if errorlevel 2 echo
>if errorlevel 0 echo文件复制没有错误。

才能正确执行。

再举几个例子:

@echo off
net usertest
IF %ERRORLEVEL% == 1 echo net user 执行失败了!
pause

这个是判断上一条命令是否执行失败的

@echo off
set /p var=随便输入个命令:
%var%
if %ERRORLEVEL% == 0 goto yes
goto no
:yes
echo !var! 执行成功了
pause
exit
:no
echo 基本上执行失败了..
pause

这个是根据你输入的命令，自动判断是成功还是失败了!

再举一个简化版的例子：

@echo off
set /p var=随便输入个命令:
%var%
if %ERRORLEVEL% == 0 (echo %var%执行成功了) ELSE echo %var%执行失败了!
pause

else后面写上执行失败后的操作。
当然我门还可以把if else这样的语句分成几行写出来，使他看上去好看点…，看这个例子

@echo off
set /p var=随便输入个命令:
%var%
if %ERRORLEVEL% == 0  (
   echo !var! 执行成功了
   ) ELSE (
   echo 基本上执行失败了..
   )
pause

这里介绍的两种简写对IF的三种语法都可以套用，不单单是在IF [NOT] ERRORLEVEL number command
这种法上才能用

¶用法2：IF [NOT] string1==string2 command

这个是用来比较变量或者字符的值是不是相等的。

例如：

@echo off
set /p var=请输入第一个比较字符:
set /p var2=请输入第二个比较字符:
if %var% == %var2% (echo 我们相等) ELSE echo 我们不相等
pause

上面这个例子可以判断你输入的值是不是相等，如果输入相同的字符，而其中一个后面多了一个空格，这个例子还是会认为相等，如何让有空格的输入不相等呢？我们在比较字符上加个双引号（如下）就可以了。

@echo off
set /p var=请输入第一个比较字符:
set /p var2=请输入第二个比较字符(多输入个空格试试):
if "%var%" == "%var2%" (echo 我们相等) ELSE echo 我们不相等
pause

¶用法3：IF [NOT] EXIST filename command

这个用来判断某个文件或者文件夹是否存在。

例子：

@echo off
if exist "c:\test" (echo 存在文件) ELSE echo 不存在文件
pause

判断的文件路径加引号是为了防止路径有空格，如果路径有空格加个双引号就不会出现判断出错了。

另外，我们看到每条IF用法后都有个[NOT]语句，加上NOT的话，就表示判断条件是否不成立，没加NOT默认是判断条件是否成立。比如上面的例子，加个NOT就表示要判断C:\test文件是否不存在，如果你的C盘下没c:\test，条件成立，则会执行echo 文件不存在的命令，结果正好与实际相反，因此要加入not，应将命令写成下面这样：

@echo off
if not exist "c:\test" (echo 不存在文件) ELSE echo 存在文件
pause

¶用法4：IF增强的用法

IF [/I] string1 compare-op string2 command  #参数/I表示不区分大小写
IF CMDEXTVERSION number command
IF DEFINED variable command  #判断变量是否存在，很有用

CMDEXTVERSION 条件的作用跟 ERRORLEVEL 的类似，它是在跟与命令扩展名有关联的内部版本号比较。第一个版本是 1。每次对命令扩展名有相当大的增强时，版本号会增加一个。命令扩展名被停用时，CMDEXTVERSION 条件不是真的。

如果已定义环境变量，DEFINED 条件的作用跟 EXISTS 的一样

IF DEFINED variable command
IF NOT "variable"=="" command

上面两条命令效果一样。

用set variable=命令使变量variable变成未定义，即空值（变量值为空，则为未定义；变量值不为空，则为已定义）。

注意：
用语句IF DEFINED variable command判断变量是否存在时，请注意variable为不使用引导符号%的变量名，因此不能用写为%variable%，否则出错。

例：

if defined aa (echo 变量aa存在) else (echo 变量aa不存在)

运行显示：

变量aa不存在

例

set aa=123
set aa=
if defined aa (echo 变量aa存在) else (echo 变量aa不存在)

运行显示：

变量aa不存在

例：

@echo off
if a == A (echo 我们相等) ELSE echo 我们不相等
pause

执行后会显示：

我们不相等

例

@echo off
if /i a == A (echo 我们相等) ELSE echo 我们不相等
pause

加上/I不区分大小写，因此直接结果为：我们相等。

最后面还有一些用来判断数字的符号

EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于